@echo off

REM Derniere MAJ : 31-10-2001

REM ================================================================================
REM                           initialisation des variables
REM ================================================================================

REM Indiquer le nom de l'ordinateur distant
set _OrdiDistant=Hd10Go-2001
REM ---------------------------------------------------------------------------------

REM Indiquer le nom de l'ordinateur Source
set _OrdiSource=df-MsNet
REM ---------------------------------------------------------------------------------

REM Chemin contenant les elements pour installation
set _VNCFile=\\%_OrdiSource%\VNC-Labo
REM ---------------------------------------------------------------------------------

REM Affectation du Nom de partage du rpertoire WinNt utilis sur ordinateur distant
set _SysRoot=admin$
REM ---------------------------------------------------------------------------------

REM Chemin distant pour la destination des fichiers
set _DestFile=\\%_OrdiDistant%\%_SysRoot%\system32
REM ---------------------------------------------------------------------------------

REM Chemin sur l'ordinateur distant pour lancer le service
set _ServicePath=c:\Winnt\System32\WinVnc.exe
REM ---------------------------------------------------------------------------------

REM Arret du service sur l'ordinateur distant
echo Arret du service WinVNC en cours
echo --------------------------------
sc  \\%_OrdiDistant% stop winvnc
echo.

REM Suppression du service sur l'ordinateur distant
echo Suppression du service WinVNC
echo --------------------------------
sc \\%_OrdiDistant% delete WinVNC
echo.

REM Suppression des anciens fichiers
echo Suppression de la version anterieure en cours
echo ----------------------------------------------
del %_DestFile%\omnithread_rt.dll
del %_DestFile%\vnchooks.dll
del %_DestFile%\winvnc.exe
echo.
pause

REM Installation des nouveaux fichiers
echo Installation de la nouvelle version en cours
echo --------------------------------------------
copy %_VNCFile%\winvnc.exe %_DestFile%
copy %_VNCFile%\omnithread_rt.dll %_DestFile%
copy %_VNCFile%\vnchooks.dll %_DestFile%
echo.
pause


REM Mise a jour de la Base de registre
echo Suppression de l'ancienne cle ORL de la Base de registre
echo --------------------------------------------------------
set _CLE=HKLM\Software\ORL
reg DELETE \\%_OrdiDistant%\%_CLE% /f

echo Ecriture de la nouvelle cle ORL de la Base de registre
echo --------------------------------------------------------
reg COPY \\%_OrdiSource%\%_CLE% \\%_OrdiDistant%\%_CLE% /s /f

REM Installation de l'icone VNC dans la barre des taches
set _CLE=HKLM\Software\Microsoft\Windows\CurrentVersion\Run
set _WinVnc=%_ServicePath%" -servicehelper"
REM si vous voulez voir l'icone de VNC sur le poste distant pret de l'horloge
REM activer la ligne suivante en enlevant le rem au debut de la ligne
rem reg add \\%_OrdiDistant%\%_CLE% /v WinVNC /t REG_SZ /d %_WinVnc% /f
echo.

pause

REM Installation de WinVNC en mode service
echo Installation du service WinVNC
echo -------------------------
sc \\%_OrdiDistant% create WinVNC binpath= "%_ServicePath% -service" type= own type= interact start= auto
echo.

REM Activation du service WinVNC
echo Activation du service WinVNC
echo -----------------------
sc  \\%_OrdiDistant% start winvnc
echo.

REM Suppression des variables
REM ------------------------------
set _CLE=
set _DestFile=
set _OrdiDistant=
set _OrdiSource=
set _ServicePath=
set _SysRoot=
set _VNCFile=
set _WinVnc=

:FIN
echo Fin
pause


